// convert microscope images using LOCI bio-formats to tif-files
// mainly written to convert Olympus FV1000 oib-files created 
// with the Multi-Area-Time-Lapse (MATL)
// written by Stefan Terjung, ALMF@EMBL Heidelberg  (stefan.terjung@embl.de)
// based on "bfOpenAsHyperstack.txt" by Wayne Rasband
// Last updated on 2008 September 8 v1.0
// modified by William Pu to assign colors to channels and optionally output single RGB.
// run as a macro from ImageJ or FIJI
	
	requires("1.41c");   //requires ImageJ 1.41c or newer
	//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	// requires LOCI bio-formats plugins (does not run with every LOCI bio-formats version, the one I tested 
	// is available from http://www.embl.de/almf/html/oib_to_tiff.htm
	// I recommend to first try the newest "stable release" available from 
	// http://www.loci.wisc.edu/ome/formats-download.html
	//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	/////////////   padwidth defines the number of digits for the counters in the filename (for t, z, c)
	padwidth = 4;
/////////////   adjust to your needs
	inDir = getDirectory("Choose the Source Directory ");
	outDir = getDirectory("Choose the Destination Directory ");	
	print("Source folder: "+inDir);
	print("Destination folder: "+outDir);
	Dialog.create("choose save options");
	Dialog.addCheckbox("save single frames", false);
	Dialog.addCheckbox("save colored images of each timepoint", true);
	Dialog.show();
	saveFrame = Dialog.getCheckbox();
	saveStack = Dialog.getCheckbox();	
	
	if (saveStack) {
		//	
		// Color mapping dialog
		//
	  numchannel=5;
	  labels = newArray(numchannel);
	  labels[0]="Blue";
	  labels[1]="Green";
	  labels[2]="Red";
	  labels[3]="Grays";
	  labels[4]="Magenta";
	  default_label=newArray(numchannel);
	  default_label[0]=0;
	  default_label[1]=1;
	  default_label[2]=2;
	  default_label[3]=3;
	  default_label[4]=4;
	  channel_color=newArray(numchannel);
	  Dialog.create("Choose Channel to Color Mapping");
	  for (i=0; i<numchannel; i++) {
	    Dialog.addChoice("Ch"+i+1,labels,labels[default_label[i]]);
	    }
	  Dialog.addCheckbox("save as single RGB image", false);
	  Dialog.show();
	  for (i=0; i<numchannel; i++) {
	  	channel_color[i]=Dialog.getChoice();
	  	}
	  singleRGB = Dialog.getCheckbox();

	  for (i=0; i<numchannel; i++)
    	 print("Ch"+i+1+": "+channel_color[i]);
	  print("singleRGB: "+singleRGB);
	  }
	  
	list = getFileList(inDir);
	run("Bio-Formats Macro Extensions");
	for (f=0; f<list.length; f++){
		Ext.setId(inDir+list[f]);
		Ext.getCurrentFile(file);
		Ext.getSeriesCount(seriesCount);
		print("seriesCount= "+seriesCount);
		Ext.getSeries(seriesNum);
//		print("get seriesNum= "+seriesNum);
/////////////	the following variable chooses the series in the file, e.g. oib to be loaded
		seriesNum=0;
/////////////	change the value above to the series you want to load (check with LOCI)
//		print("set seriesNum= "+seriesNum);
		heightConvert="";
		field="Image 0 : HeightConvertValue";
	 	val="";
 		Ext.getMetadataValue(field,val);
	 	    if (val != 0)
 		      heightConvert=val;
//		print("heightConvertValue: "+heightConvert);
		widthConvert="";
	 	field="Image 0 : WidthConvertValue";
 		val="";
	 	Ext.getMetadataValue(field,val);
 		if (val != 0)
 			widthConvert=val;
//		print("widthConvertValue: "+widthConvert); 
		Ext.setSeries(seriesNum);
		Ext.getSeriesName(seriesName);
//		print("seriesName: "+seriesName);
		Ext.getSizeX(sizeX);
		Ext.getSizeY(sizeY);
		Ext.getSizeC(sizeC);
		Ext.getSizeZ(sizeZ);
		Ext.getSizeT(sizeT);
		Ext.getImageCount(n);
		print(file+":", sizeX, sizeY+" Ch:"+ sizeC+" z:"+ sizeZ+" t:"+ sizeT+"PixSize: "+heightConvert+" n:"+ n +" sCount:"+ seriesCount +" sNum: "+  seriesNum +" sName: "+ seriesName);
		setBatchMode(true);
		i=0;
		for (t=0; t<sizeT; t++){
			for (z=0; z<sizeZ; z++){
				for (c=0; c<sizeC; c++){
					  showProgress(i, n);
					  Ext.openImage("plane "+i, i);
					if (saveFrame){
						  fpad = leftPad (f, padwidth);
						  zpad = leftPad (z, padwidth);
						  cpad = leftPad (c, padwidth);
						  tpad = leftPad (t, padwidth);	
						  run("Set Scale...", "distance=1 known="+heightConvert+" pixel=1 unit=micron");				  
						  saveAs("Tiff", outDir+"r"+fpad+"_z"+zpad+"_c"+cpad+"_t"+tpad+"_"+list[f]);
						  print("saving: "+outDir+"r"+fpad+"z"+zpad+"c"+cpad+"t"+tpad+list[f]);
						} 
					if (saveStack){
						  if (i==0)
						    stack = getImageID;
						  else {
						    run("Copy");
						    close;
						    selectImage(stack);
						    run("Add Slice");
						    run("Paste");
						  }
					}
					i++;
				}
			}
	}
	if (saveStack){
		Out_Name="Stack";
		rename(list[f]);
		if (nSlices>1) {
		  Stack.setDimensions(sizeC, sizeZ, sizeT);
		  if (sizeC>1) {
		    run("Make Composite", "display=Composite");

// set colors according to channel choices		    
		    for (i=0;i<sizeC;i++) {
		    	setSlice(i+1);
				run(channel_color[i]);
				}
		   	if (singleRGB) {
		    	run("Stack to RGB");
		    	Out_Name="Single";
			}
		  }
		setOption("OpenAsHyperStack", true);
		run("Set Scale...", "distance=1 known="+heightConvert+" pixel=1 unit=micron");
		fpad = leftPad (f, padwidth);
		saveAs("Tiff", outDir+Out_Name+"_r"+fpad+"_"+list[f]);
		}
	}
	//setBatchMode(false);
	close();
	Ext.close();
}
print("finished");


//digits padding
function leftPad(n, width) {
    s =""+n;
    while (lengthOf(s)<width)
        s = "0"+s;
    return s;
}